FIND_PACKAGE(OpenGL)
FIND_PACKAGE(Boost 1.34.1 COMPONENTS filesystem unit_test_framework serialization)
FIND_PACKAGE(Qt4)
INCLUDE( ${QT_USE_FILE} )
INCLUDE(Platform)

# dont you love the number of \ you need to make sure the " shows up in
# the C compiler?
SET(EXAMPLE_DIR ${CMAKE_SOURCE_DIR}/examples)
IF(WIN32)
  STRING(REGEX REPLACE "/" "\\\\\\\\\\\\\\\\" EXAMPLE_DIR ${EXAMPLE_DIR})
ENDIF(WIN32)

# get our platform specific flags
GET_MUSSA_COMPILE_FLAGS(ALG_TEST_CFLAGS)
GET_MUSSA_LINK_FLAGS(ALG_TEST_LDFLAGS)

SET(ALG_TEST_LIBS
      mussa_core
      ${QT_LIBRARIES}
      ${Boost_FILESYSTEM_LIBRARY}
      ${Boost_UNIT_TEST_FRAMEWORK_LIBRARY} 
      ${Boost_SERIALIZATION_LIBRARY}
      ${OPENGL_gl_LIBRARY}
)

MACRO(MAKE_ALG_UNITTEST basename)
  SET(${basename}_SRC ${basename}.cpp)
  SET_SOURCE_FILES_PROPERTIES(${${basename}_SRC} 
      COMPILE_FLAGS "-DEXAMPLE_DIR=\\\"${EXAMPLE_DIR}\\\" ${ALG_TEST_CFLAGS}"
  )
  ADD_EXECUTABLE(${basename} ${${basename}_SRC})
  TARGET_LINK_LIBRARIES(${basename} ${ALG_TEST_LIBS})
  
  SET_TARGET_PROPERTIES(
    ${basename}
    PROPERTIES
    COMPILE_FLAGS "${ALG_TEST_CFLAGS}"
    LINK_FLAGS "${ALG_TEST_LDFLAGS}"
  )
  ADD_TEST(${basename} ${basename})
ENDMACRO(MAKE_ALG_UNITTEST)

#add all our main tests
MAKE_ALG_UNITTEST( test_alphabet )
MAKE_ALG_UNITTEST( test_annotations )
MAKE_ALG_UNITTEST( test_annotation_color )
MAKE_ALG_UNITTEST( test_color )
MAKE_ALG_UNITTEST( test_conserved_path )
MAKE_ALG_UNITTEST( test_drawable )
MAKE_ALG_UNITTEST( test_flp )
MAKE_ALG_UNITTEST( test_glseqbrowser )
MAKE_ALG_UNITTEST( test_glsequence )
MAKE_ALG_UNITTEST( test_mussa )
MAKE_ALG_UNITTEST( test_nway )
MAKE_ALG_UNITTEST( test_seq )
MAKE_ALG_UNITTEST( test_sequence )
MAKE_ALG_UNITTEST( test_seq_span )
MAKE_ALG_UNITTEST( test_sequence_location )

IF(USE_PAIRCOMP)
  INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/paircomp/lib )
  MAKE_ALG_UNITTEST( test_paircomp )
  TARGET_LINK_LIBRARIES( test_paircomp paircomplib )
ENDIF(USE_PAIRCOMP)