htsworkflow/templates/trackhub_samples.sparql

   1 PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
   2 PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
   3 PREFIX htswlib: <http://jumpgate.caltech.edu/wiki/LibraryOntology#>
   4 PREFIX submissionOntology: <http://jumpgate.caltech.edu/wiki/UcscSubmissionOntology#>
   5 PREFIX ucscDaf: <http://jumpgate.caltech.edu/wiki/UcscDaf#>
   6 PREFIX ncbiTaxon: <http://www.ncbi.nlm.nih.gov/Taxonomy/Browser/wwwtax.cgi?id=>
   7 PREFIX trackdb: <http://genome.ucsc.edu/goldenPath/help/trackDb/trackDbHub.html#>
   8 PREFIX geoSoft: <http://www.ncbi.nlm.nih.gov/geo/info/soft2.html#>
   9 PREFIX cells: <http://encodewiki.ucsc.edu/EncodeDCC/index.php/Cell_lines#>
  10 PREFIX encode3: <http://jumpgate.caltech.edu/wiki/Encode3#>
  11
  12 select distinct ?lab_library_id ?library_id ?filename ?relative_path ?output_type ?file_type ?cell ?replicate ?assay ?rna_type ?protocol ?file_label ?autoScale ?maxHeightPixels ?visibility
  13 WHERE {
  14   ?trackType trackdb:type ?file_type ;
  15              ucscDaf:output_type ?output_type .
  16   OPTIONAL { ?trackType trackdb:autoScale ?autoScale . }
  17   OPTIONAL { ?trackType trackdb:maxHeightPixels ?maxHeightPixels . }
  18   OPTIONAL { ?trackType trackdb:visibility ?visibility . }
  19   ?file ucscDaf:filename ?filename ;
  20         ucscDaf:relative_path ?relative_path ;
  21         htswlib:library ?library ;
  22         a ?trackType .
  23   OPTIONAL { ?file rdfs:label ?file_label . }
  24   OPTIONAL { ?library htswlib:library_id ?lab_library_id }
  25   OPTIONAL { ?library encode3:library_id ?library_id }
  26   OPTIONAL { ?library htswlib:cell_line ?cell . }
  27   OPTIONAL { ?library htswlib:replicate ?replicate }
  28   OPTIONAL { ?library encode3:assay ?assay . }
  29   OPTIONAL { ?library encode3:rna_type ?rna_type. }
  30   OPTIONAL { ?library encode3:protocol ?protocol. }
  31   #OPTIONAL { ?library ucscDaf:readType ?read_type }
  32 }
  33 order by ?trackType